12个函数公式，解决表格中按条件多列求和，你需要哪个？

【温馨提示】 亲爱的朋友，阅读之前请您点击【关注】，您的支持将是我最大的动力！

Excel 表格中数据求和，可以说最常的数据计算操作。我们都知道普通求和用快捷键最方便，也有 SUM 函数，按条件求和用 SUMIF 函数，多条件求和用 SUMIFS 函数。

那么你知道按条件多列求和怎么操作呢？今天阿钟老师分享几个函数公式来解决，各具特色，看看你的工作中需要哪一种？

实例： 下图表格中，要求计算各产品的前三个月销量合计数；

分析： 求和的条件产品在 B 列，求和的数据区域在 C、D、E 三列。

01：

=SUMIF(B:B,G2,C:C)+SUMIF(B:B,G2,D:D)+SUMIF(B:B,G2,E:E)

这个公式不难理解，就是三个 SUMIF 函数分别对 C、D、E 三列求和后再相加，得出计算结果。

02：

=SUM(IF(B$2:B$13=G2,C$2:E$13))

注意： 这是一个数组函数，公式输入完成后要按 Ctrl+Shift+ 回车键确认公式，再双击或下拉填充公式。

公式利用 IF 函数判断满足条件的数据，再用 SUM 函数实现求和。

03：

=SUM((B$2:B$13=G2)*C$2:E$13)

这也是一个数组公式，需要按 Ctrl+Shift+ 回车键确认公式，再双击或下拉填充公式。

这个公式与上一个比较省了 IF 函数判断，利用 B$2:B$13=G2 产生的逻辑值（0 和 1）与数据区域相乘。

04：

=SUMPRODUCT((B$2:B$13=G2)*C$2:E$13)

这个公式原理和上一个一样，区别在于回车键确认公式即可，省去三键确认的麻烦。

以上公式比较简单，也能满足日常工作需求。

接下来讲的公式相对有些难度，如果喜欢函数公式的可以继续看下去。

05：

=SUMPRODUCT((B$2:B$13=G2)*MMULT(C$2:E$13,{1;1;1}))

06：

=SUM(MMULT((B$2:B$13=G2)*C$2:E$13,{1;1;1}))

这两个公式比较相似，弄懂的话需要先看看 MMULT 函数的用法。

MMULT 函数

【用途】 计算两个数组的矩阵乘数

【语法】MMULT（数组 1，数组 2）

07：

=SUM(SUMIF(B:B,G2,OFFSET(B:B,,{1,2,3})))

这个公式利用 OFFSET 函数对求和数据区域偏移，构造多区域数据，分别得到三列的求和。

08：

=SUM(SUMIF(B:B,G2,INDIRECT("C"&{3,4,5},)))

与上一公式相似，用 INDIRECT 函数构造多区域数据。

09：

=SUM(SUMIF(B:B,G2,INDIRECT({"C","D","E"}&1)))

和上一公式相同，INDIRECT 函数换了一种单元格引用方式。

10：

=SUM(DSUM(A$1:E$13,{3,4,5},G$1:G2))-SUM(H$1:H1)

公式中 DSUM 函数为数据库类的求和函数，计算数据库中指定条件的记录之和。

11：

=SUMPRODUCT(COUNTIF(G2,B$2:B$13)*C$2:E$13)

公式中利用 COUNTIF 函数来判断，类似 02 公式中的 IF 函数判断。

12：

=MMULT(MMULT(N(G2:G6=TRANSPOSE(B2:B13)),C2:E13),{1;1;1})

数组公式，并且需要先选中结果区域 H2：H6，输入公式后按 Ctrl+Shift+ 回车键确认公式，得出计算结果，不必再双击或下拉填充公式。较难理解，关注我后面的教程陆续推出详细教程。

小伙伴们，在使用 Excel 中还碰到过哪些问题，评论区留言一起讨论学习，坚持原创不易，您的点赞转发就是对小编最大的支持，更多教程点击下方专栏学习。

销售统计员要注意了，学会这 6 个 Excel 函数，快速完成销售统计

表格中经常做合并单元格操作的注意了，如何实现筛选数据呢？

12 个 Excel 表格实用操作技巧，有批量插入空行、按颜色筛选等等